external_cryo_geometry Subroutine

    subroutine external_cryo_geometry
        !! Calculate cryostat geometry
        !! author: J. Morris, CCFE, Culham Science Centre
        !! Calculate cryostat geometry
        !
        ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

        use constants, only: pi
        use build_variables, only: clhsf, hmax, tfcth, ddwex
        use fwbs_variables, only: rdewex, rpf2dewar, zdewex, vdewex, vvmass, vdewin, &
          denstl, dewmkg
        use pfcoil_variables, only: rb, zh
        use buildings_variables, only: clh1

        implicit none

        ! cryostat radius (m)
        ! ISSUE #508 Remove RFP option
        ! rb(i) = outer radius of PF coil i (tokamaks)
        rdewex = maxval(rb) + rpf2dewar

        ! Clearance between uppermost PF coil and cryostat lid (m).
        ! Scaling from ITER by M. Kovari
        hcryopf = clhsf * (2.0D0*rdewex)/28.440D0

        ! Half-height of cryostat (m)
        ! ISSUE #508 Remove RFP option
        zdewex = maxval(zh) + hcryopf

        ! Vertical clearance between TF coil and cryostat (m)
        clh1 = zdewex - (hmax + tfcth)

        ! cryostat volume (m3)
        vdewex = ( (2.0D0*pi*rdewex) * 2.0D0*zdewex + (2.0D0*pi*rdewex**2) ) * ddwex

        ! Vacuum vessel mass (kg)
        vvmass = vdewin * denstl

        ! Sum of internal vacuum vessel and cryostat masses (kg)
        dewmkg = (vdewin + vdewex) * denstl

    end subroutine external_cryo_geometry